批处理读取配置文件并作相应处理-阿里云开发者社区

批处理读取配置文件并作相应处理

2017-11-26 1464

版权

本文内容由阿里云实名注册用户自发贡献，版权归原作者所有，阿里云开发者社区不拥有其著作权，亦不承担相应法律责任。具体规则请查看《阿里云开发者社区用户服务协议》和《阿里云开发者社区知识产权保护指引》。如果您发现本社区中有涉嫌抄袭的内容，填写侵权投诉表单进行举报，一经查实，本社区将立刻删除涉嫌侵权内容。

简介：

需求：读取station.ini文件，创建父节点(上、下、客场站集)文件夹到D盘，并根据配置拷贝当前文件夹下各个目录到指定的父节点文件夹。

以下为.bat文件内容：

@echo off & setlocal enabledelayedexpansion
COLOR 0a
FOR /F "eol=; tokens=1* delims==" %%i IN (G:\Source\station.ini) do (
    set p=%%i
    set q=%%j
    if "!p:~0,1!"=="[" (
        if "!p:~-1!"=="]" (
            rem 获取站名
            set name=!p:~1,-1!
        )
    )else (
        set fatherNm=!p!
        set fileNm=!q!
        if "!fatherNm!"=="fatherName" (
            rem 获取父节点名称并创建文件夹
            if not exist d:\!fileNm! md d:\!fileNm!
            set creatFile=!fileNm!
        )
    )
    if not "!name!"=="" (
        if not "!creatFile!"=="" (
            rem 拷贝G:\Source下各个文件夹到对应的站集遍历G:\Source文件
            for /d %%a in (*) do (
                set sonFileNm=%%a
                if "!sonFileNm!"=="!name!" (
                    if not exist d:\!creatFile!\!sonFileNm! (
                        rem 以下赋值目的在于剔除末尾空格
                        set covertFileNm=!creatFile: =!
                        xcopy "G:\Source\!sonFileNm!" "d:\!covertFileNm!\!sonFileNm!\" /e/h/r/y
                    ) else (
                    echo 存在同名文件&goto :eof
                    )
                )
            )
            set name=
            set creatFile=
         )
    )
)
pause