ORACLE 异常错误处理-阿里云开发者社区

即使是写得最好的PL/SQL程序也会遇到错误或未预料到的事件。一个优秀的程序都应该能够正确处理各种出错情况，并尽可能从错误中恢复。任何ORACLE错误（报告为ORA-xxxxx形式的Oracle错误号）、PL/SQL运行错误或用户定义条件（不一写是错误），都可以。当然了，PL/SQL编译错误不能通过PL/SQL异常处理来处理，因为这些错误发生在PL/SQL程序执行之前。
ORACLE 提供异常情况(EXCEPTION)和异常处理(EXCEPTION HANDLER)来实现错误处理。

1 异常处理概念
异常情况处理(EXCEPTION)是用来处理正常执行过程中未预料的事件,程序块的异常处理预定义的错误和自定义错误,由于PL/SQL程序块一旦产生异常而没有指出如何处理时,程序就会自动终止整个程序运行.

有三种类型的异常错误：
1．预定义 ( Predefined )错误
ORACLE预定义的异常情况大约有24个。对这种异常情况的处理，无需在程序中定义，由ORACLE自动将其引发。
2．非预定义 ( Predefined )错误
即其他标准的ORACLE错误。对这种异常情况的处理，需要用户在程序中定义，然后由ORACLE自动将其引发。
3．用户定义(User_define) 错误
程序执行过程中，出现编程人员认为的非正常情况。对这种异常情况的处理，需要用户在程序中定义，然后显式地在程序中将其引发。

异常处理部分一般放在 PL/SQL 程序体的后半部,结构为:

EXCEPTION
WHEN first_exception THEN <code to handle first exception >
WHEN second_exception THEN <code to handle second exception >
WHEN OTHERS THEN <code to handle others exception >

END;

异常处理可以按任意次序排列,但 OTHERS 必须放在最后.

1 预定义的异常处理
预定义说明的部分 ORACLE 异常错误
ORACLE 异常错误处理
所有错误代码和描述，文件在$ORACLE_HOME/rdbms/mesg/oraus.msg
对这种异常情况的处理，只需在PL/SQL块的异常处理部分，直接引用相应的异常情况名，并对其完成相应的异常错误处理即可。
例1：更新指定员工工资，如工资小于1500，则加100；
D:\instantclient_12_2>sqlplus hr/hr@pdbtest

SQL*Plus: Release 12.2.0.1.0 Production on Thu Dec 21 09:55:15 2017

Last Successful login time: Wed Dec 20 2017 10:59:38 +08:00

Connected to:
Oracle Database 12c Enterprise Edition Release 12.2.0.1.0 - 64bit Production

SQL> set serveroutput on
SQL> DECLARE
2 v_empno employees.employee_id%TYPE := &empno;
3 v_sal employees.salary%TYPE;
4 BEGIN
5 SELECT salary INTO v_sal FROM employees WHERE employee_id = v_empno;
6 IF v_sal<=1500 THEN
7 UPDATE employees SET salary = salary + 100 WHERE employee_id=v_empno;
8 DBMS_OUTPUT.PUT_LINE('编码为'||v_empno||'员工工资已更新!');
9 ELSE
10 DBMS_OUTPUT.PUT_LINE('编码为'||v_empno||'员工工资已经超过规定值!');
11 END IF;
12 EXCEPTION
13 WHEN NO_DATA_FOUND THEN
14 DBMS_OUTPUT.PUT_LINE('数据库中没有编码为'||v_empno||'的员工');
15 WHEN TOO_MANY_ROWS THEN
16 DBMS_OUTPUT.PUT_LINE('程序运行错误!请使用游标');
17 WHEN OTHERS THEN
18 DBMS_OUTPUT.PUT_LINE(SQLCODE||'---'||SQLERRM);
19 END;
20 /
Enter value for empno: 7782
old 2: v_empno employees.employee_id%TYPE := &empno;
new 2: v_empno employees.employee_id%TYPE := 7782;
数据库中没有编码为7782的员工

PL/SQL procedure successfully completed.
2 非预定义的异常处理

对于这类异常情况的处理，首先必须对非定义的ORACLE错误进行定义。步骤如下：

在PL/SQL 块的定义部分定义异常情况：

<异常情况> EXCEPTION;

将其定义好的异常情况，与标准的ORACLE错误联系起来，使用EXCEPTION_INIT语句：
PRAGMA EXCEPTION_INIT(<异常情况>, <错误代码>);
在PL/SQL 块的异常情况处理部分对异常情况做出相应的处理。

例1：删除指定部门的记录信息，以确保该部门没有员工。
SQL> DECLARE
2 v_deptno departments.department_id%TYPE := &deptno;
3 deptno_remaining EXCEPTION;
4 PRAGMA EXCEPTION_INIT(deptno_remaining, -2292);
5 / -2292 是违反一致性约束的错误代码 /
6 BEGIN
7 DELETE FROM departments WHERE department_id = v_deptno;
8 EXCEPTION
9 WHEN deptno_remaining THEN
10 DBMS_OUTPUT.PUT_LINE('违反数据完整性约束!');
11 WHEN OTHERS THEN
12 DBMS_OUTPUT.PUT_LINE(SQLCODE||'---'||SQLERRM);
13 END;
14 /
Enter value for deptno: 50
old 2: v_deptno departments.department_id%TYPE := &deptno;
new 2: v_deptno departments.department_id%TYPE := 50;
违反数据完整性约束!

PL/SQL procedure successfully completed.
3 用户自定义的异常处理
当与一个异常错误相关的错误出现时，就会隐含触发该异常错误。用户定义的异常错误是通过显式使用 RAISE 语句来触发。当引发一个异常错误时，控制就转向到 EXCEPTION块异常错误部分，执行错误处理代码。

对于这类异常情况的处理，步骤如下：
1．在PL/SQL 块的定义部分定义异常情况：

<异常情况> EXCEPTION;

2． RAISE <异常情况>；

3．在PL/SQL 块的异常情况处理部分对异常情况做出相应的处理。

例1：更新指定员工工资，增加100；
SQL> DECLARE
2 v_empno employees.employee_id%TYPE :=&empno;
3 no_result EXCEPTION;
4 BEGIN
5 UPDATE employees SET salary = salary+100 WHERE employee_id = v_empno;
6 IF SQL%NOTFOUND THEN
7 RAISE no_result;
8 END IF;
9 EXCEPTION
10 WHEN no_result THEN
11 DBMS_OUTPUT.PUT_LINE('你的数据更新语句失败了!');
12 WHEN OTHERS THEN
13 DBMS_OUTPUT.PUT_LINE(SQLCODE||'---'||SQLERRM);
14 END;
15 /
Enter value for empno: 5000
old 2: v_empno employees.employee_id%TYPE :=&empno;
new 2: v_empno employees.employee_id%TYPE :=5000;
你的数据更新语句失败了!

PL/SQL procedure successfully completed.
4 用户定义的异常处理

调用DBMS_STANDARD(ORACLE提供的包)包所定义的RAISE_APPLICATION_ERROR过程，可以重新定义异常错误消息，它为应用程序提供了一种与ORACLE交互的方法。

RAISE_APPLICATION_ERROR 的语法如下：

RAISE_APPLICATION_ERROR(error_number,error_message,[keep_errors] );

这里的error_number 是从 –20,000 到 –20,999 之间的参数，
error_message 是相应的提示信息(< 2048 字节)，

keep_errors 为可选，如果keep_errors =TRUE ,则新错误将被添加到已经引发的错误列表中。如果keep_errors=FALSE(缺省),则新错误将替换当前的错误列表。

例1：定义触发器，使用RAISE_APPLICATION_ERROR阻止没有员工姓名的新员式记录插入：
CREATE OR REPLACE TRIGGER tr_insert_emp
BEFORE INSERT ON employees
FOR EACH ROW
BEGIN
IF :new.first_name IS NULL OR :new.last_name is null THEN
RAISE_APPLICATION_ERROR(-20000,'Employee must have a name.');
END IF;
END;
5.异常错误传播
由于异常错误可以在声明部分和执行部分以及异常错误部分出现，因而在不同部分引发的异常错误也不一样。
在执行部分引发异常错误
当一个异常错误在执行部分引发时，有下列情况：
l 如果当前块对该异常错误设置了处理，则执行它并成功完成该块的执行，然后控制转给包含块。
l 如果没有对当前块异常错误设置定义处理器，则通过在包含块中引发它来传播异常错误。然后对该包含块执行步骤1)。
在声明部分引发异常错误

如果在声明部分引起异常情况，即在声明部分出现错误，那么该错误就能影响到其它的块。比如在有如下的PL/SQL程序：

DECLARE
name varchar2(12):='EricHu';
其它语句
BEGIN
其它语句
EXCEPTION
WHEN OTHERS THEN
其它语句
END;
异常错误处理编程
在一般的应用处理中，建议程序人员要用异常处理，因为如果程序中不声明任何异常处理，则在程序运行出错时，程序就被终止，并且也不提示任何信息。下面是使用系统提供的异常来编程的例子。
在 PL/SQL 中使用 SQLCODE, SQLERRM异常处理函数
由于ORACLE 的错信息最大长度是512字节，为了得到完整的错误提示信息，我们可用 SQLERRM和 SUBSTR 函数一起得到错误提示信息，方便进行错误，特别是如果WHEN OTHERS异常处理器时更为方便。

SQLCODE 返回遇到的Oracle错误号,
SQLERRM 返回遇到的Oracle错误信息.

如: SQLCODE=-100 è SQLERRM=’no_data_found ‘
SQLCODE=0 è SQLERRM=’normal, successfual completion’
例1. 将ORACLE错误代码及其信息存入错误代码表
CREATE TABLE errors (errnum NUMBER(4), errmsg VARCHAR2(100));

DECLARE
err_msg VARCHAR2(100);
BEGIN
/ 得到所有 ORACLE 错误信息 /
FOR err_num IN -100 .. 0 LOOP
err_msg := SQLERRM(err_num);
INSERT INTO errors VALUES(err_num, err_msg);
END LOOP;
END;
DROP TABLE errors;

本文转自whshurk 51CTO博客，原文链接：http://blog.51cto.com/shurk/2052790，如需转载请自行联系原作者

ORACLE 异常错误处理

热门文章

最新文章

相关电子书

推荐镜像