[自制简单操作系统] 1、从0-1到汇编再到c语言的奥秘

  1. 云栖社区>
  2. 博客>
  3. 正文

[自制简单操作系统] 1、从0-1到汇编再到c语言的奥秘

史迪奇2号 2017-08-31 01:02:00 浏览966
展开阅读全文


 


目录:

1、用0-1编写最简单的操作系统

2、用汇编改写上面0-1程序

  2.1 只用DB的汇编改写版  2.2 加入RESB汇编的改写版  2.3 进一步使用汇编替换0-1文件  2.4 核心程序也用汇编改写  2.5 向汇编程序中加入IPL(启动程序装载器)  2.6 从启动区执行操作系统(读盘的应用)

3、汇编和C语言混合开发

  3.1 32位开发及C语言混合开发引入 3.2 汇编引入C语言(用汇编写C语言函数)  3.3 C语言实现内存写入  3.4 C语言指针的强大  3.5 色号设定与调色板 3.6 简单界面实现


 

1、用0-1编写最简单的操作系统

>_<" 用二进制编辑器(Binary Editor),输入下面的内容(这里是16进制的)

PS: 如上图,蓝色部分要仔细,下面一直到168000这个地址都是00,在0001F0和001400附近还有些地方不是0,要把他们改过来,检查一遍,保存为helloos.img

>_<" 将这个文件写入软盘用来启动电脑就能显示“hello,world”这个字符串。

PS: 上面界面是用了一个PC模拟器


 

2、用汇编改写上面0-1程序

>_<" 这里就把上述超长的0-1文件改成汇编语言文件helloos.nas,然后调用nask.exe编译器将.nas文件编译为.img~剩下的就不用说了~

2.1 只用DB的汇编改写版

复制代码
1 DB    0xeb, 0x4e, 0x90, 0x48, 0x45, 0x4c, 0x4c, 0x4f
2 DB    0x49, 0x50, 0x4c, 0x00, 0x02, 0x01, 0x01, 0x00
3 DB    0x02, 0xe0, 0x00, 0x40, 0x0b, 0xf0, 0x09, 0x00
4 DB    0x12, 0x00, 0x02, 0x00, 0x00, 0x00, 0x00, 0x00
5 DB    0x40, 0x0b, 0x00, 0x00, 0x00, 0x00, 0x29, 0xff
6 (为节省纸张,这里省略18万4314行)
7 DB    0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00
复制代码

PS:DB是data byte的缩写,就是往文件里直接写入1字节的指令~这样就实现了汇编实现最上面的0-1文件,但是貌似看起来更长了....(如果足够牛B的话,只用DB就能做出任何文件)

 

2.2 加入RESB汇编的改写版

复制代码
 1 DB    0xeb, 0x4e, 0x90, 0x48, 0x45, 0x4c, 0x4c, 0x4f
 2 DB    0x49, 0x50, 0x4c, 0x00, 0x02, 0x01, 0x01, 0x00
 3 DB    0x02, 0xe0, 0x00, 0x40, 0x0b, 0xf0, 0x09, 0x00
 4 DB    0x12, 0x00, 0x02, 0x00, 0x00, 0x00, 0x00, 0x00
 5 DB    0x40, 0x0b, 0x00, 0x00, 0x00, 0x00, 0x29, 0xff
 6 DB    0xff, 0xff, 0xff, 0x48, 0x45, 0x4c, 0x4c, 0x4f
 7 DB    0x2d, 0x4f, 0x53, 0x20, 0x20, 0x20, 0x46, 0x41
 8 DB    0x54, 0x31, 0x32, 0x20, 0x20, 0x20, 0x00, 0x00
 9 RESB    16
10 DB    0xb8, 0x00, 0x00, 0x8e, 0xd0, 0xbc, 0x00, 0x7c
11 DB    0x8e, 0xd8, 0x8e, 0xc0, 0xbe, 0x74, 0x7c, 0x8a
12 DB    0x04, 0x83, 0xc6, 0x01, 0x3c, 0x00, 0x74, 0x09
13 DB    0xb4, 0x0e, 0xbb, 0x0f, 0x00, 0xcd, 0x10, 0xeb
14 DB    0xee, 0xf4, 0xeb, 0xfd, 0x0a, 0x0a, 0x68, 0x65
15 DB    0x6c, 0x6c, 0x6f, 0x2c, 0x20, 0x77, 0x6f, 0x72
16 DB    0x6c, 0x64, 0x0a, 0x00, 0x00, 0x00, 0x00, 0x00  ;到000080前8个的内容,后8个和000090之后填0,部分做修改
17 RESB    368
18 DB    0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x55, 0xaa  ;这就是0001F0处非0的内容
19 DB    0xf0, 0xff, 0xff, 0x00, 0x00, 0x00, 0x00, 0x00
20 RESB    4600
21 DB    0xf0, 0xff, 0xff, 0x00, 0x00, 0x00, 0x00, 0x00  ;伙计发现没,这就是001400地址处的内容
22 RESB    1469432
复制代码

PS: 这里多加入了一个汇编指令RESB,就使文件大致清新多了~这里RESB指令是reserve byte的缩写,如果想从某个字节开始空出10个字节就能写成RESB 10,这样我们就节约了大约10万行代码~

 

2.3 进一步使用汇编替换0-1文件

>_<" 虽然上面把10几万行的0-1改写的只有20几行,但是还是无法理解其意思,下面进行优化,使我们能理解代码的意思~

复制代码
 1 ; hello-os
 2 ; TAB=4
 3 
 4 ; 以下段落是标准FAT12格式软盘专用代码
 5     DB    0xeb, 0x4e, 0x90  ; 注意和我们写的0-1代码,以及上面几个版本的对比一下,你就会明白的
 6     DB    "HELLOIPL"        ; 启动区的名称可以是任意字符串(8字节)
 7     DW    512              ; 每个扇区(sector)的大小必须为512字节
 8     DB    1               ; 簇(cluster)的大小必须为1个扇区
 9     DW    1               ; FAT的起始位置(一般从第一个扇区开始)
10     DB    2               ; FAT的个数(必须为2)
11     DW    224              ; 根目录的大小(一般设为244项)
12     DW    2880             ; 该磁盘的的大小(必须为2880扇区)
13     DB    0xf0             ; 磁盘的种类(必须为0xfd)
14     DW    9                ; FAT的长度(必须为9扇区)
15     DW    18               ; 一个磁道(track)有几个扇区(必须为18)
16     DW    2                ; 磁头数(必须为2)
17     DD    0                ; 不使用分区(必须为0)
18     DD    2880             ; 重写一次磁盘大小
19     DB    0,0,0x29         ; 意义不明,固定
20     DD    0xffffffff       ; (可能是)卷标号码
21     DB    "HELLO-OS   "    ; 磁盘名称(11字节)
22     DB    "FAT12   "       ; 磁盘格式名称(8字节)
23     RESB    18             ; 先腾出18字节
24 
25 ; 程序主体
26     DB    0xb8, 0x00, 0x00, 0x8e, 0xd0, 0xbc, 0x00, 0x7c
27     DB    0x8e, 0xd8, 0x8e, 0xc0, 0xbe, 0x74, 0x7c, 0x8a
28     DB    0x04, 0x83, 0xc6, 0x01, 0x3c, 0x00, 0x74, 0x09
29     DB    0xb4, 0x0e, 0xbb, 0x0f, 0x00, 0xcd, 0x10, 0xeb
30     DB    0xee, 0xf4, 0xeb, 0xfd
31 
32 ; 信息显示部分
33     DB    0x0a, 0x0a        ; 2个换行
34     DB    "hello, world"
35     DB    0x0a              ; 换行
36     DB    0
37 
38     RESB    0x1fe-$            ; 填写0x00直到0x001fe
39     DB    0x55, 0xaa
40 
41 ; 以下是启动区以外部分的输出
42     DB    0xf0, 0xff, 0xff, 0x00, 0x00, 0x00, 0x00, 0x00
43     RESB    4600
44     DB    0xf0, 0xff, 0xff, 0x00, 0x00, 0x00, 0x00, 0x00
45     RESB    1469432
复制代码

PS: 不用解释,程序主体放在下面讲,如何转换为容易理解的汇编~

 

2.4 核心程序也用汇编改写

>_<" 这里主要对上面改进版汇编的25~36行进行改写为更容易理解的汇编程序(最开头也改动一点点),其他一样:

复制代码
 1 ; hello-os
 2 ; TAB=4
 3         ORG        0x7c00            ; 指明程序的装载地址
 4 ; 以下段落是标准FAT12格式软盘专用代码
 5         JMP        entry
 6         DB        0x90
 7         DB        "HELLOIPL"        ; 启动区的名称可以是任意字符串(8字节)
 8         DW        512                ; 每个扇区(sector)的大小必须为512字节
 9         DB        1                ; 簇(cluster)的大小必须为1个扇区
10         DW        1                ; FAT的起始位置(一般从第一个扇区开始)
11         DB        2                ; FAT的个数(必须为2)
12         DW        224                ; 根目录的大小(一般设为244项)
13         DW        2880            ; 该磁盘的的大小(必须为2880扇区)
14         DB        0xf0            ; 磁盘的种类(必须为0xfd)
15         DW        9                ; FAT的长度(必须为9扇区)
16         DW        18                ; 一个磁道(track)有几个扇区(必须为18)
17         DW        2                ; 磁头数(必须为2)
18         DD        0                ; 不使用分区(必须为0)
19         DD        2880            ; 重写一次磁盘大小
20         DB        0,0,0x29        ; 意义不明,固定
21         DD        0xffffffff        ; (可能是)卷标号码
22         DB        "HELLO-OS   "    ; 磁盘名称(11字节)
23         DB        "FAT12   "        ; 磁盘格式名称(8字节)
24         RESB    18                ; 先腾出18字节
25 
26 ; 程序核心
27 entry:
28         MOV        AX,0            ; 初始化寄存器
29         MOV        SS,AX
30         MOV        SP,0x7c00
31         MOV        DS,AX
32         MOV        ES,AX
33 
34         MOV        SI,msg          ;主程序就是把msg的内容给SI然后循环逐个输出
35 putloop:
36         MOV        AL,[SI]
37         ADD        SI,1            ; SI++
38         CMP        AL,0
39         JE        fin
40         MOV        AH,0x0e            ; 显示一个文字
41         MOV        BX,15            ; 指定字符颜色
42         INT        0x10            ; 调用显卡BIOS(汇编中经常会用到的一种调用形式)
43         JMP        putloop
44 fin:
45         HLT                        ; 让CPU停止等待指令(和在main函数的结尾写一个getchar()类似)
46         JMP        fin                ; 无限循环
47 
48 msg:
49         DB        0x0a, 0x0a        ; 2个回车
50         DB        "hello, world"
51         DB        0x0a            ; 回车
52         DB        0
53 
54         RESB    0x7dfe-$        ; 填充0
55 
56         DB        0x55, 0xaa
57 
58 ; 以下是启动区以外部分的输出
59         DB        0xf0, 0xff, 0xff, 0x00, 0x00, 0x00, 0x00, 0x00
60         RESB    4600
61         DB        0xf0, 0xff, 0xff, 0x00, 0x00, 0x00, 0x00, 0x00
62         RESB    1469432
复制代码

PS: 这里我们可以方便的看出来,原来主程序的功能就是把msg里面的字符先传给SI然后SI++遍历循环输出的意思,哈哈,终于能完整的从0-1转到汇编然后理解0-1的意思啦~

PS: 这里刚开始的125字节就是启动区125字节内容,其地址为0x00007c00-0x00007dff,所以第3行指明程序加载地址~

 

2.5 向汇编程序中加入IPL(启动程序装载器)

>_<" 上面的汇编实现了将msg的字符串显示到显示屏上,但是这里的msg是本来保存在内存中的,一般CPU的内存是很小的,如果把大量的信息(如整个操作系统)都保存在这里肯定是不合理的,因此就需要把这部分内容存储在其他上(如内存条,这里采用软盘)!因此,我们就要在核心程序初始化之后从软盘读取数据放到内存在执行~(下面是调用INT 0x13读取磁盘的相关代码)

复制代码
 1 ; 读磁盘(从软盘中读数据装到内存中0x8200--0x83ff  125字节的地方)
 2 MOV        AX,0x0820        ;ES:BX=缓冲地址
 3 MOV        ES,AX
 4 MOV        CH,0            ; 柱面0
 5 MOV        DH,0            ; 磁头0
 6 MOV        CL,2            ; 扇区2
 7 
 8 MOV        AH,0x02            ; AH=0x02 : 读盘
 9 MOV        AL,1            ; 1个扇区
10 MOV        BX,0
11 MOV        DL,0x00            ; A驱动器
12 INT        0x13            ; 调用磁盘BIOS
13 JC        error
复制代码

 >_<" 修改后的汇编代码如下:(这里从磁盘读取数据装到0x8200--0x83ff 125字节的地方,如果读取出错就跳转到error,显示读取出错这个内容~

 从磁盘读取内容IPL

 

2.6 从启动区执行操作系统(读盘的应用)

>_<" 软盘这种东西不可靠,因此我们要多次读盘尝试,如果多次之后还不行再放弃读盘,读盘代码改动如下:

 5次读盘的核心代码
 5次读盘的全部代码

>_<" 趁着上面的尽头,咱们直接写个从扇区2读到扇区18的代码吧!

PS:这里采用的思路是:把扇区2->18的内容读到内存,内存刚开始的地址为0x0820,每次读一个扇区向后移动0x0200个地址(即:125字节)

 读取到18扇区的核心代码
 读取到18扇区的完整代码

>_<" 趁热打铁,C0-H0-S18的下一扇区就是磁盘的反面C0-H1-S1,这次是要从C0-H0-S2---->C0-H0-S3----->C9-H1-S18

 读取10个柱面的核心代码
 读取10个柱面的全部代码

 

3、汇编和C语言混合开发

3.1 32位开发及C语言混合开发引入

>_<" 现在我们已经学会如何从磁盘读数据放到内存中了,那么下面就是如何将操作系统本身内容写进磁盘映像,然后我们从启动区执行这个内容就行了~

>_<" 前两部分我们已经把操作系统的引导程序写好了,即是最终的读取10个柱面的全部代码,我们通过编译就能把其编译为磁盘镜像文件(即最上面看的0-1文件);接下来新建一个haribote.nas汇编文件,在里面先写上如下代码,这就是一个简单的操作系统内容文件,用nask编译为.sys格式的文件,保存到磁盘映像.img里(这个过程比较复杂,其实有比较好的软件可以帮助我们直接解决上述保存到磁盘映像的问题:edimg.exe) 。这里文件保存到映像文件时有一个规律:

  • 文件名会在0x002600以后的地方出现
  • 文件的内容会写在0x004200后的地方

 根据上面的规律,我们就可以将操作系统本身的内容写到名为haribote.sys文件中,再把他们保存到磁盘映像里,然后我们从启动区执行这个haribotes.sys就行了。

1 fin:
2         HLT                        ; 让CPU停止等待指令
3         JMP        fin                ; 无限循环

>_<" 那么该怎样才能执行磁盘映像上位于0x004200号地址的程序呢?我们在第二节已经介绍,程序是从启动区开始执行,把磁盘上的内容装在到内存0x8000号地址,所以磁盘0x4200处的内容位于内存0x8000+0x4200=0xc200号地址处。 这样我们在haribote.nas里加上ORG 0xc200,然后在第二节最后读取10个柱面的全部代码(下面命名为ipl.nas)加上JMP 0xc200。

复制代码
1 ; haribote-os
2 ; TAB=4
3 
4         ORG        0xc200            
5 fin:
6         HLT
7         JMP        fin
复制代码

这样将上面两个文件编译并合并为映像文件并运行,什么都没有发生,那么我们想看看程序到底有没有运行,该则么办呢?其实很简单,就像我们刚学C++的时候让程序输出个hello world,但是这里,因为我们上两节已经实现了这个功能,再玩一遍没啥意思,于是,这里来个高级一点的:这次切换一下画面模式(因为我们最终要做成windows那样地画面),因此需要把在我们的haribote.nas内添加一些内容(主要是调用显卡BIOS的函数,具体搜索INT 0x10):

复制代码
 1 ; haribote-os
 2 ; TAB=4
 3 
 4         ORG        0xc200            ; 这个程序要被装在到程序的什么位置
 5 
 6         MOV        AL,0x13            ; VGA显卡,320X200X8位彩色
 7         MOV        AH,0x00
 8         INT        0x10
 9 fin:
10         HLT
11         JMP        fin
复制代码

这样如果程序正常运行,画面将是一片漆黑,光标会消失。另外,我们将ipl.nas的文件名改成ipl10.nas(提醒大家,这个程序只能读入10个柱面),另外,想要把磁盘装在内容的结束地址告诉haribote.sys,所以我们要在JMP 0xc200之前加上一行命令,将CYLS的值写到地址0x0ff0中,这样启动程序就修改好了~

1 ; 磁盘内容装载内容的结束地址告诉haribote.sys
2 
3         MOV        [0x0ff0],CH        ; 将CYLS的值写到内存地址0x0ff0中 
4         JMP        0xc200
 ipl10.nas(启动程序)

PS: 这里我们把启动区里与haribote.sys无关的前后部分也读了进来,所以启动很慢,但是以后会有用的~

>_<" 现在,汇编语言开发终于可以告一段落啦~,接下来我们主要以C语言开发为 主了~因为这里用的是32位C语言编译器(32位模式比16位的要好很多,这里不详细说明了),但是32位模式就不能调用BIOS功能了(这是因为BIOS是由16位机器语言写的,如果我们有什么事情想用BIOS来做,就要全部放在开头做,一旦进入32位模式就不能调用BIOS函数了(其实也有32位返回16位的方法)。再回头说说使用BIOS的事情,在上面我们已经把画面模式设定已经做完了,接下来还想从BIOS获取键盘状态(即:NumLock是ON还是OFF),这次只修改了haribote.nas:

复制代码
 1 ; haribote-os
 2 ; TAB=4
 3 
 4 ; BOOT_INFO相关
 5 CYLS    EQU        0x0ff0            ; 设定启动区
 6 LEDS    EQU        0x0ff1
 7 VMODE    EQU        0x0ff2            ; 关于颜色的信息颜色的位数
 8 SCRNX    EQU        0x0ff4            ; 分辨率X
 9 SCRNY    EQU        0x0ff6            ; 分辨率Y
10 VRAM    EQU        0x0ff8            ; 图像缓冲区的开始地址
11 
12         ORG        0xc200            ; 这个程序要装载到什么地方
13 
14         MOV        AL,0x13            ; VGA显卡,320X200X8位色彩
15         MOV        AH,0x00
16         INT        0x10
17         MOV        BYTE [VMODE],8    ; 记录画面模式
18         MOV        WORD [SCRNX],320
19         MOV        WORD [SCRNY],200
20         MOV        DWORD [VRAM],0x000a0000
21 
22 ; 用BIOS获得键盘上各种LED指示灯的状态
23 
24         MOV        AH,0x02
25         INT        0x16             ; keyboard BIOS
26         MOV        [LEDS],AL
27 
28 fin:
29         HLT
30         JMP        fin
复制代码

这个程序一看就明白,其实就是设置画面模式之后,将设置的信息保存到内存中(以后可能要设置不同的画面模式,就要把现在的设置信息保存起来以备后用);[VRAM]里保存的是0xa0000,在电脑的世界里,VRAM是指显卡内存(Video RAM)也就是显示画面的内存,这一块可以像一般的内存一样存储数据,但VRAM的功能不仅限于此,它的各个地址都对应着画面上的像素,可以利用这一机制在画面上绘制出五颜六色的图案~

 

3.2 汇编引入C语言(用汇编写C语言函数)

>_<" 终于准备就绪了,现在我们直接切换到32位模式,然后运行C语言程序,这次要修改很多:首先是haribote.sys,它的前半部分是用汇编写的,后半部分是用C语言写的,所以为了方便把文件名也从haribote.nas也随之改成了asmhead.nas,并且为了调用C语言在前面加了100行左右的汇编代码(今后再详细介绍这100行代码)下面先把到这里全部的代码贴出来(我猜很多人已经晕了,不知道到底是哪些文件了)

 ipl10.asm(负责读取磁盘加载主程序)
 asmhead.asm
 bootpack.c

下面说一下C语言部分:(以后为了启动操作系统还需要很多处理函数,所以就把这些处理函数打成一个包,为了好理解就取了bootpack名字),这里有c语言基础的人一眼就懂这个简单程序的意思了~关键是它如何变成机器语言的呢?下面就是详细过程:

  • 首先:使用cc1.exe从bootpack.c生成bootpack.gas[这一步主要实现将c语言编译为gas汇编]
  • 第二步:使用gas2nask.exe从bootpack.gas生成bootpack.nas[这一步主要实现从gas汇编到nas汇编]
  • 第三步:使用nask.exe从bootpack.nas生成bootpack.obj[将nas汇编编译为机器语言]
  • 第四步:使用bim2bim.exe从bootpack.obj生成bootpack.bim[制成二进制映像文件]
  • 第五步:使用bim2hrb.exe从bootpack.bim生成bootpack.hrb[将映像制成对应操作系统所需要的文件]
  • 最后:这样就做成了机器语言,再适用copy指令将asmhead.bin和bootpack.hrb单纯结合起来,就制成了haribote.sys[合并形成系统文件]

PS: 1) C语言编译生成的汇编不是nask汇编,所以要有1、2两步将c语言转换为nask汇编

   2) 我们用从C语言转换来的nask汇编然后转换成的机器语言是一种特殊的obj机器语言,必须与其他文件链接(link)之后才能形成真正可以运行的机器语言

   3) 这里我们把obj转换为bim映像其实就是将各个分部分链接在一起,做成一个完整的机器文件

   4) 此外,我们为了能让上面完整的机器语言实际使用,还要针对不同操作系统进行必要的加工,比如说加上识别文件头、压缩等

PS: 有人在windows和linux上也做过很多次C语言开发,但是也没有这么烦,说到底,是人家的编译器已经很成熟啦!我们为了要开发出适用不同平台的操作系统甚至是自己的操作系统,就没有将中间的过程省略~

PS: 这里的HariMain不要改动名字[因为程序要从这个地方开始运行,就像main函数的main]

>_<" 这里又要新建一个文件了:naskfunc.nas 它的功能就是用汇编写一些函数,供c语言调用(因为上面已经说过,32位模式下无法适用BIOS等功能),这个文件里主要写一些要用汇编实现的功能函数~

复制代码
 1 ; naskfunc
 2 ; TAB=4
 3 
 4 [FORMAT "WCOFF"]                ; 制成目标文件的形式    
 5 [BITS 32]                        ; 制作32模式用的机器语言
 6 
 7 
 8 ; 制作目标文件信息
 9 
10 [FILE "naskfunc.nas"]            ; 源文件名信息
11 
12         GLOBAL    _io_hlt            ; 程序中包含的函数名
13 
14 
15 ; 以下是实际的函数
16 
17 [SECTION .text]        ; 目标文件中写了这些后再写程序
18 
19 _io_hlt:    ; void io_hlt(void);
20         HLT
21         RET
复制代码

PS: 用汇编写的函数,之后还要与bootpack.obj链接,所以也需要编译成目标文件。因此将输出格式设置为WCOFF模式,另外还要设置为32位机器语言模式。在nask目标文件的模式下,必须设定文件名信息,然后再写明下面函数的名,注意这里的函数名前面要加”-“并且声明为GLOBAL。再往下就是实际的函数了,这里很简单~这里在bootpack.c要调用这个函数很简单,如下:

复制代码
 1 /* 告诉c编译器,有一个函数在别的文件里 */
 2 
 3 void io_hlt(void);
 4 
 5 void HariMain(void)
 6 {
 7 
 8 fin:
 9     io_hlt(); /*执行naskfunc.nas里的_io_hlt*/
10     goto fin;
11 }
复制代码

 

3.3 C语言实现内存写入

>_<" 上面已经实现了让画面黑屏,但是只做到这一点没意思,还是在画面上画点东西比较有趣。想要画东西的话,只要往VRAM里写点东西就可以了,但是c语言中又没有直接写入指定内存地址的语句(其实是有的,一步步来)。所以我们直接用汇编写一个函数,在naskfunc.nas里添加如下部分:

1 _write_mem8:    ; void write_mem8(int addr, int data);
2         MOV        ECX,[ESP+4]        ; [ESP+4]中存放的是地址,将其读入ECX
3         MOV        AL,[ESP+8]        ; [ESP+8]中存放的是数据,将其读入AL
4         MOV        [ECX],AL
5         RET
 naskfunc。nas全部代码[除了上面说的函数外,还有其他部分也做了修改]

上面的函数在c语言里调用write_mem8(0x1234,0x56);语句时,就相当于MOV BYTE[0x1234],0x56。如果C语言中调用了write_mem8函数,就会跳转到_write_mem8。此时参数指定的数字就是放在内存里,分别是:

  • 第一个数字的存放地址:[ESP+4]
  • 第二个数字的存放地址:[ESP+8]
  • 第三个数字的存放地址:[ESP+12]
  • 第四个数字的存放地址:[ESP+16]
  • (依次类推...)

那么在bootpack.c里面调用这个函数填写VRAM内存的方法如下:

复制代码
 1 void io_hlt(void);
 2 void write_mem8(int addr, int data);
 3 
 4 void HariMain(void)
 5 {
 6     int i; /* 声明变量i,i是一个32位的整数 */
 7 
 8     for (i = 0xa0000; i <= 0xaffff; i++) { //遍历VRAM地址,每个写入15
 9         write_mem8(i, 15); /* MOV BYTE [i],15 */
10     }
11 
12     for (;;) {
13         io_hlt();
14     }
15 }
复制代码

效果如下:整个屏幕变成了白色,这是因为向VRAM内都写入的15,意思是所有颜色都是第15个颜色,而第15个颜色正好是纯白色!

 

现在我们稍微改动一下,写入VRAM中的变量看看会有啥效果,我们将循环中的write_mem8(i,15)改成write_mem8(i,i & 0x0f),效果如下:我们这种写法就相当于每次写入i%16,所以每个16个像素,色号就反复一次,而整体呈现出如下的条纹图案:

 

3.4 C语言指针的强大

>_<" 上一节开头说过:c语言不能对内存进行读写,其实不是,c语言的指针能完美地完成内存读写的工作,这里就用c语言的指针代替上面用汇编写的write_mem8函数实现内存写入。

复制代码
 1 void io_hlt(void);
 2 
 3 void HariMain(void)
 4 {
 5     int i; 
 6     char *p; /*用于BYTE型地址*/
 7 
 8     for (i = 0xa0000; i <= 0xaffff; i++) {
 9 
10         p = i; /* 带入地址 */
11         *p = (char*)i & 0x0f;
12 
13         /* 代替 write_mem8(i, i & 0x0f); */
14     }
15 
16     for (;;) {
17         io_hlt();
18     }
19 }
复制代码

这样我们就完美的代替了汇编写的write_mem8函数,不得感叹一句指针真实强大(其实关于指针的很多细节,这里实在说不了了,但是它很强大,很强大~)!这里只说几点:

  • char *p;是BYTE类地址--short *p;是用于WORD类地址--int *p是用于DWORD类地址
  • 其实这样写就不用声明个p了:((char *)i)=i & 0x0f    ps:这种写法和BYTE[i]=i & 0x0f有些像吧
  • p表示地址,*p表示地址的内容
  • char *p是声明p,一般把*靠在p上是为了想声明2个指针时更清晰:char *p,*q;
  • *(p+i)也可以写成p[i]形式,但是这里p[i]不是数组,因为这里*(p+i)可以*(i+p)也行,即i[p]也对

 

3.5 色号设定与调色板

>_<" 我们想通过上面的内存写入可以画出一些乱的图案,但是我们想具体画一些东西的时候就要考虑颜色问题了。这里我们采用的是320X200的8位颜色模式,色号使用8位(二进制数),也就是只能从0~255的数。熟悉电脑颜色的人应该知道这是很少的,像电脑里一般用6位16进制的数,即24位(二进制数)来指定颜色。那么该怎样来指定颜色呢?

>_<" 这个8位色彩模式,是由程序员随意指定0~255的数字所对应的颜色。比如:25号对应#ffffff,26号对应#123456,如果像刚才那样程序员不做任何指定,0号就是#000000,15号就是#ffffff。这里我们想要制作个操作系统,因此由前辈的经验知道,只要用以下16种颜色就够了:

  • #000000:黑    #00ffff:浅亮色    #000084:暗蓝    #ff0000:亮红    #ffffff:白    #840084:暗紫    #00ff00:亮绿    #c6c6c6:亮灰
  • #008484:浅暗蓝   #ffff00:亮黄    #840000:暗红    #848484:暗灰    #0000ff:亮蓝    #008400:暗绿    #ff00ff:亮紫    #848400:暗黄

所以要对bootpack.c进行较大的修改:

 新的bootpack.c
 新的naskfunc.nas

PS: 这里要做几点说明(这篇文章说的太多了,不多说还说不清,早知道不把这么多放在一起了!)

1)访问调色板的步骤:(具体参照bootpack.c中的set_palette函数)

  • 屏蔽中断(CLI)
  • 将想要设定的调色板号写入0x03c8,紧接着按着R,G,B的顺序写入0x03c9,如果想继续设定下一个调色板,省略调色板号,继续按照RGB顺序写入0x03c9
  • 想要读出当前调色板的状态,首先要将调色板号写入0x03c7,再从0x03c9依次读3次,分别是R,G,B,如果想继续读取下一个,也是省略调色板号的设定继续读取
  • 如果最初执行了CLI那么要恢复中断STI

2)中断标志位的读取和设置要涉及到栈的应用,这里看一下代码就理解了(前提是你得懂栈这种数据结构)

3)在set_palette中要注意关闭中断与恢复中断,这个在操作系统中特别是嵌入式操作系统中应用较多

现在运行一下程序看看效果:[仔细看,和上面那个条纹图有点不一样吧]

 

3.6 简单界面实现

>_<" 上面我们已经把调色板配好了,接下来看看我们的绘画能力了,这里我们稍微改动一下bootpack.c里面的函数,实现画矩形的功能:

 绘制矩形例子的bootpack.c

>_<" 进一步我们绘制一个像样点的窗口:[哈哈,有点那个意思了吧!]

 绘制一个窗口的bootpack.c文件
 
 
LZ说明:没想到一口气竟然说了这么多,总结一下,其实就揭示了一个过程:编译器是如何从c等高级语言转换为机器语言然后控制硬件呈现效果的~里面涉及的知识略多,有些确实不能用几句话说完~明天就要上课了,今天就到这里吧~(http://www.cnblogs.com/zjutlitao/)
 



本文转自beautifulzzzz博客园博客,原文链接:http://www.cnblogs.com/zjutlitao/p/3945852.html,如需转载请自行联系原作者

网友评论

登录后评论
0/500
评论
史迪奇2号
+ 关注